Tutoriel Opensimworld

3 posts / 0 new
Last post
#1 Mon, 22/05/2017 - 09:34
No picture available
Cherry Manga

Tutoriel Opensimworld

Pour ajouter sa région au site de destinations http://opensimworld.com/

1 Créer son compte

2 Aller dans l'onglet Regions puis add your region

Rentrer les données,

ajouter des images, une description

3 Inworld, créer un cube (ou tout autre objet) et inserer le script ci dessous modifié par Ssm:

string wkey = "";
// ============================================================
//      NOTHING SHOULD BE MODIFIED UNDER THIS LINE
// ============================================================
string BASEURL="http://opensimworld.com/index.php/osgate";
string regionName = "";
string status;
integer minsSinceLast = 0;
string s_rating;
key beaconHttp;
integer nTotalAvis =-1;

checkBeacon()
{
    regionName = llGetRegionName();
    list g = osGetAgents();
    integer nNew = llGetListLength(g);
    // Find out how many of them are NPCs
    list avis = osGetAvatarList(); // This will not return the owner
    integer howmany = llGetListLength(avis);
    integer i;
    for (i =0; i < howmany; i+=3)
        if (osIsNpc(llList2Key(avis, i)))
            nNew--;

    if (nNew<0) nNew=0;
   
    if (nNew != nTotalAvis || minsSinceLast > 30)
    {
       nTotalAvis = nNew;
       string url=BASEURL+"/beacon/?wk="+wkey+"&na="+(string)nTotalAvis+"&r="+llEscapeURL(regionName)+"&rat="+s_rating+"&pos="+llEscapeURL((string)llGetPos());
       beaconHttp = llHTTPRequest(url, [], "");
       minsSinceLast = 0;
    }

}

// on change (taken from d4os regions guide)
onChange(integer change)
{
    if (change & CHANGED_INVENTORY)
    {
        llResetScript();
    }

    if (change & CHANGED_OWNER)
    {
        llResetScript();
    }
 
    if (change & CHANGED_LINK)
    {
        llResetScript();
    }
 
    if (change & CHANGED_REGION)
    {
        llResetScript();
    }
 
    if (change & CHANGED_REGION_START)
    {
        llResetScript();
    }
}

default
{
    on_rez(integer n)
    {
        llResetScript();
    }
   
    state_entry()
    {
        llSetText("", ZERO_VECTOR, 1.0);
        if (wkey != "")
        {
            checkBeacon();
            llSetTimerEvent(60);
            key gRateingQuery = llRequestSimulatorData( llGetRegionName(), DATA_SIM_RATING );
        }
        else
        {
            llOwnerSay("The wkey is missing. Script stopped.");
        }
    }
   
    timer()
    {
        checkBeacon();
        minsSinceLast++;
    }
   
    dataserver(key query_id, string data)
    {
        s_rating = data;
    }

    http_response(key request_id, integer stcode, list metadata, string body)
    {
        if (request_id == beaconHttp)
        {
            if (body == "OK")
            {
                llOwnerSay("Server received the request.");
            }
            else
            {
                llOwnerSay("Server: "+body+"");
            }
        }
    }

    changed(integer change)
    {
        onChange(change);
    }
}

Sur opensimworld, une clef vous est donnée pour votre région (floutée sur l'image ci -dessous)

Cette clef est à inserer dans votre script, à la premiere ligne entre les ""

string wkey = "";

Voilà, votre région est enregistrée sur opensimworld!

Vous pouvez modifier les informations, ajouter des images, et ajouter d'autres régions à visiter!

Mon, 22/05/2017 - 10:57
No picture available
Archael Magic

Excellent travail, merci !

Excellent travail, merci !

Mon, 22/05/2017 - 17:40
No picture available
Praline B

Merci

Efficace et très utile comme tutoriel.

Merci ! ;)